Exercices - (In)Equations logarithmiques et exponentielles

Unprotect[Log];
Log/:Format[Log[x_]]:= ln[x];
EnSol[x≤a_]:=StringForm["⟵ , ``]",a];
EnSol[x<a_]:=StringForm["⟵ , `` [",a];

EnSol[x>a_]:=StringForm["] ``, ⟶",a] ;
EnSol[x≥a_]:=StringForm["[ ``, ⟶",a];

EnSol[Inequality[a_,LessEqual,x,LessEqual,b_]]:=StringForm["[ `` , `` ]",a,b] ;

EnSol[Inequality[a_,Less,x,Less,b_]]:=StringForm["] `` , `` [",a,b] ;

EnSol[a_<x<b_]:=StringForm["] `` , `` [",a,b] ;
EnSol[a_≤x≤b_]:=StringForm["[ `` , `` ]",a,b] ;
EnSol[a_<x≤b_]:=StringForm["] `` , `` ]",a,b] ;
EnSol[a_≤x<b_]:=StringForm["[ `` , `` [",a,b] ;

EnSol[x==a_]:=StringForm["{``}",a];
EnSol[x≠a_]:=StringForm["ℝ \\ {``}",a];
EnSol[c_ x+b_≠a_]:=StringForm["ℝ \\ {``}",(a-b)/c];
EnSol[ x+b_≠a_]:=StringForm["ℝ \\ {``}",(a-b)];
EnSol[Or[x<a_,a_<x<b_,x>b_]]:=StringForm["ℝ \\ {`1`,`2`}",a,b];
EnSol[Or[x==a_,x==b_]]:=StringForm["{`1` , `2`}",a,b];


EnSol[Or[e1_,e2_]]:= EnSol[Or[e2,e1]]/; Head[e1]==Greater;

EnSol[Or[e1_,e2_]]:= StringForm["`1`  ⋃  `2 `",EnSol[e1],EnSol[e2]];
EnSol[Or[x<a_,x>a_]]:= StringForm["ℝ \\ {``}",a];
EnSol[Or[Less[x,a_],Inequality[a_,Less,x,Less,b_],Greater[x,b_]]]:= StringForm["ℝ \\ {``,``}",a,b];

EnSol[True]=ℝ;
EnSol[False]=∅;
Null

Résoudre

equation[1]=(3^(x-2)-1/9==0);
equation[2]=(16-E^(2x)==0);
equation[3]=(HoldForm[Log[x,27]]==-3);
equation[4]=(HoldForm[Log[10,3x+7]]==2HoldForm[Log[10,5]]);
equation[5]=(Log[2x^2+x]==0);
equation[6]=(Log[5x]-Log[x+1]==Log[2]);
equation[7]=(Log[3-x]==Log[x]);
equation[8]=(2Log[x]-Log[x-1]==2Log[2]);
equation[9]=(Log[(x+3)/2]==1/2*(Log[x]+Log[3]));
equation[10]=(HoldForm[Log[2,x]]==2HoldForm[Log[2,3]]-HoldForm[Log[2,x-5]]+2);
equation[11]=(HoldForm[Log[10,x+3]]+HoldForm[Log[10,x+5]]==HoldForm[Log[10,15]]);
equation[12]=(Log[x-2]+Log[x+2]-Log[3]==Log[15]);
equation[13]=(2Log[x-4]==Log[x]-2Log[2]);
equation[14]=(Log[x^2+5x+6]==Log[x+11]);
equation[15]=(HoldForm[Log[3,4x+1]]+HoldForm[Log[3,x+2]]-2HoldForm[Log[3,3x]]==0);
equation[16]=(2Log[1-x]+Log[2x+3]-Log[x+1]==2Log[3]);
equation[17]=(HoldForm[Log[10,x^2+2x-3]]-2HoldForm[Log[10,x-1]]==2);
equation[18]=(Log[x]+Log[x-1]==Log[x+3]);
equation[19]=(3Log[x]-Log[x+2]==Log[2]);
equation[20]=(2E^(2x)-11E^x+15==0);
equation[21]=(4^x+6==5*2^x);
equation[22]=(Log[x] (Log[x]+2)==-1);
equation[23]=(Log[x] (3Log[x]+5)==2);

(* inéquations *)
equation[24]=(5^x<1/2);
equation[25]=(HoldForm[Log[8,x]]≥2/3);
equation[26]=(HoldForm[Log[10,6-x]]>1);
equation[27]=(E^x-1/E≥0);
equation[28]=(HoldForm[Log[1/2,x+4]]>HoldForm[Log[1/2,2x-3]]);
equation[29]=(Log[x^2+3]≥2Log[2]+Log[x]);
equation[30]=(49^x≥(7)^(x-1));
equation[31]=(E^(3x-1)-9>0);
equation[32]=(2^(2x)-5*2^x+2^2≤0);

equation[33]=((Log[x]-1)/Log[x]≥1);
equation[34]=((Log[x]-2)/Log[x]<0);
equation[35]=((Log[x]+1)/(Log[x]-1)<0);

Do[solution[i]=(EnSol[Reduce[ReleaseHold[equation[i]],x,Reals]]),{i,35}];
Do[Print[i,") ",equation[i]],{i,35}];

Solutions

Do[Print[i,") S = ",solution[i]],{i,35}];